PlanToolBarIndicators.qml

Go to the documentation of this file.

import QtQuick
import QtQuick.Controls
import QtQuick.Layouts
import QtQuick.Dialogs
 
import QGroundControl
import QGroundControl.Controls
import QGroundControl.FactControls
 
// Toolbar for Plan View
RowLayout {
    required property var planMasterController
    property bool showRallyPointsHelp: false
 
    signal toolbarButtonClicked()
 
    id: root
    spacing: ScreenTools.defaultFontPixelWidth
 
    property var _planMasterController: planMasterController
    property var _missionController: _planMasterController.missionController
    property var _geoFenceController: _planMasterController.geoFenceController
    property var _rallyPointController: _planMasterController.rallyPointController
    property bool _controllerOffline: _planMasterController.offline
    property var _saveDirty: _planMasterController.dirtyForSave
    property var _uploadDirty: _planMasterController.dirtyForUpload
    property var _syncInProgress: _planMasterController.syncInProgress
    property var _visualItems: _missionController.visualItems
    property bool _hasPlanItems: _planMasterController.containsItems
 
    readonly property real _margins: ScreenTools.defaultFontPixelWidth
 
    function _uploadClicked() {
        _planMasterController.upload()
    }
 
    function _downloadClicked() {
        if (_saveDirty) {
            QGroundControl.showMessageDialog(root, qsTr("Download"),
                                         qsTr("You have unsaved changes. Downloading from the Vehicle will lose these changes. Are you sure?"),
                                         Dialog.Yes | Dialog.Cancel,
                                         function() { _planMasterController.loadFromVehicle() })
        } else {
            _planMasterController.loadFromVehicle()
        }
    }
 
    function _openButtonClicked() {
        if (_saveDirty || _uploadDirty) {
            QGroundControl.showMessageDialog(root, qsTr("Open Plan"),
                                        qsTr("You have unsaved/unsent changes. Loading a new Plan will lose these changes. Are you sure?"),
                                        Dialog.Yes | Dialog.Cancel,
                                        function() { _planMasterController.loadFromSelectedFile() } )
        } else {
            _planMasterController.loadFromSelectedFile()
        }
    }
 
    function _saveButtonClicked() {
        if (_planMasterController.currentPlanFileName === "") {
            if (_planMasterController.currentPlanFile === "") {
                // No file and no name typed — open the file dialog
                _planMasterController.saveToSelectedFile()
            } else {
                // Have a file but name was cleared — save to the existing file
                _planMasterController.saveToCurrent()
            }
            return
        }
 
        if (_planMasterController.currentPlanFile === "" || _planMasterController.planFileRenamed) {
            // First save with a typed name, or name was changed since last save
            let fullName = _planMasterController.currentPlanFileName + "." + _planMasterController.fileExtension
            let msg = _planMasterController.resolvedPlanFileExists()
                ? qsTr("'%1' already exists. Overwrite?").arg(fullName)
                : qsTr("Save as '%1'?").arg(fullName)
            QGroundControl.showMessageDialog(root, qsTr("Save"), msg,
                Dialog.Yes | Dialog.No,
                function() { _planMasterController.saveWithCurrentName() })
        } else {
            _planMasterController.saveToCurrent()
        }
    }
 
    function _saveAsKMLClicked() {
        // Don't save if we only have Mission Settings item
        if (_visualItems.count > 1) {
            _planMasterController.saveKmlToSelectedFile()
        }
    }
 
    function _storageClearButtonClicked() {
        QGroundControl.showMessageDialog(root, qsTr("Clear"),
                                     qsTr("Are you sure you want to remove all the items from the plan editor?"),
                                     Dialog.Yes | Dialog.Cancel,
                                     function() { _planMasterController.removeAll(); })
    }
 
    function _vehicleClearButtonClicked() {
        QGroundControl.showMessageDialog(root, qsTr("Clear"),
                                     qsTr("Are you sure you want to remove the plan from the vehicle and the plan editor?"),
                                     Dialog.Yes | Dialog.Cancel,
                                     function() {
                                        _planMasterController.removeAllFromVehicle()
                                     })
    }
 
    function _clearClicked() {
        if (_planMasterController.offline) {
            _storageClearButtonClicked();
        } else {
            _vehicleClearButtonClicked();
        }
    }
 
    QGCPalette { id: qgcPal }
 
    QGCButton {
        text: qsTr("Open")
        iconSource: "/qmlimages/Plan.svg"
        enabled: !_planMasterController.syncInProgress
        onClicked: { toolbarButtonClicked(); _openButtonClicked() }
    }
 
    QGCButton {
        text: qsTr("Save")
        iconSource: "/res/SaveToDisk.svg"
        enabled: !_syncInProgress && _hasPlanItems
        primary: _saveDirty
        onClicked: { toolbarButtonClicked(); _saveButtonClicked() }
    }
 
    QGCButton {
        id: uploadButton
        text: qsTr("Upload")
        iconSource: "/res/UploadToVehicle.svg"
        enabled: !_syncInProgress && _hasPlanItems
        visible: !_syncInProgress
        primary: _uploadDirty
        onClicked: { toolbarButtonClicked(); _uploadClicked() }
    }
 
    QGCButton {
        text: qsTr("Clear")
        iconSource: "/res/TrashCan.svg"
        enabled: !_syncInProgress
        onClicked: { toolbarButtonClicked(); _clearClicked() }
    }
 
    QGCButton {
        iconSource: "qrc:/qmlimages/Hamburger.svg"
 
        onClicked: {
            let position = Qt.point(width, height / 2)
            // For some strange reason using mainWindow in mapToItem doesn't work, so we use globals.parent instead which also gets us mainWindow
            position = mapToItem(globals.parent, position)
            var dropPanel = hamburgerDropPanelComponent.createObject(mainWindow, { clickRect: Qt.rect(position.x, position.y, 0, 0) })
            dropPanel.open()
        }
    }
 
    QGCLabel {
        text:    qsTr("Click in map to add rally points")
        visible: root.showRallyPointsHelp
        Layout.alignment: Qt.AlignVCenter
    }
 
    Component {
        id: hamburgerDropPanelComponent
 
        DropPanel {
            id: dropPanel
 
            sourceComponent: Component {
                ColumnLayout {
                    spacing: ScreenTools.defaultFontPixelHeight / 2
 
                    QGCButton {
                        Layout.fillWidth: true
                        text: qsTr("Save as KML")
                        enabled: !_syncInProgress && _hasPlanItems
 
                        onClicked: {
                            dropPanel.close()
                            _saveAsKMLClicked()
                        }
                    }
 
                    QGCButton {
                        Layout.fillWidth: true
                        text: qsTr("Download")
                        enabled: !_syncInProgress && !_controllerOffline
                        visible: !_syncInProgress
 
                        onClicked: {
                            dropPanel.close()
                            _downloadClicked()
                        }
                    }
                }
            }
        }
    }
}