UdpSettings.qml

Go to the documentation of this file.

import QtQuick
import QtQuick.Controls
import QtQuick.Layouts
 
import QGroundControl
import QGroundControl.Controls
 
ColumnLayout {
    spacing: _rowSpacing
 
    function saveSettings() {
        // No need
    }
 
    QGCLabel {
        Layout.preferredWidth: _secondColumnWidth
        Layout.fillWidth:       true
        font.pointSize:         ScreenTools.smallFontPointSize
        wrapMode:               Text.WordWrap
        text:                   qsTr("Note: For best perfomance, please disable AutoConnect to UDP devices on the General page.")
    }
 
    RowLayout {
        spacing: _colSpacing
 
        QGCLabel { text: qsTr("Port") }
        QGCTextField {
            id:                     portField
            text:                   subEditConfig.localPort.toString()
            focus:                  true
            Layout.preferredWidth:  _secondColumnWidth
            inputMethodHints:       Qt.ImhFormattedNumbersOnly
            onTextChanged:          subEditConfig.localPort = parseInt(portField.text)
        }
    }
 
    QGCLabel { text: qsTr("Server Addresses (optional)") }
 
    Repeater {
        model: subEditConfig.hostList
 
        delegate: RowLayout {
            spacing: _colSpacing
 
            QGCLabel {
                Layout.preferredWidth:  _secondColumnWidth
                text:                   modelData
            }
 
            QGCButton {
                text:       qsTr("Remove")
                onClicked:  subEditConfig.removeHost(modelData)
            }
        }
    }
 
    RowLayout {
        spacing: _colSpacing
 
        QGCTextField {
            id:                     hostField
            Layout.preferredWidth:  _secondColumnWidth
            placeholderText:        qsTr("Example: 127.0.0.1:14550")
        }
        QGCButton {
            text:       qsTr("Add Server")
            enabled:    hostField.text !== ""
            onClicked: {
                subEditConfig.addHost(hostField.text)
                hostField.text = ""
            }
        }
    }
}